/* round_square.pov */

#include "colors.inc"
#include "textures.inc"

global_settings {
    assumed_gamma 2.2
    radiosity {
    }
}

camera {
    location <-1.4,  0.7, -2  >*2.5
    look_at  < 0  , -0.2,  0  >
}

#macro beam(d, c)
    light_source {
        100*-d
        color c
        cylinder
        radius 0.5
        falloff 4
        point_at d
    }
#end

beam( x, Cyan   )
beam(-y, Yellow )
beam( z, Magenta)

light_source {
    <0, 0, 0>
    color rgb 0.25
}

#macro stripes(d, s, w)
    gradient d
    scale    s
    color_map {
        [0     color Black] [0+w/s color Black]
        [0+w/s color White] [1-w/s color White]
        [1-w/s color Black] [1     color Black]
    }
#end

#declare xz_grid =
    plane {
        y, 0
        texture {
            pigment {
                pigment_pattern {
                    average
                    pigment_map {
                        [stripes(x, 1/1, 1/30)]
                        [stripes(x, 1/4, 1/80)]
                        [stripes(z, 1/1, 1/30)]
                        [stripes(z, 1/4, 1/80)]
                    }
                }
                color_map {
                    [0.9 color Black]
                    [0.9 color White]
                }
            }
            finish {
                ambient 0
                diffuse 0.875
            }
        }
    }

object {
    xz_grid
    translate -2*y
}

object {
    xz_grid
    rotate 90*z
    translate 2*x
}

object {
    xz_grid
    rotate -90*x
    translate 2*z
}

merge {
    cylinder {-1.0*y, 1.0*y, 0.8}
    cylinder {-0.8*y, 0.8*y, 1.0}
    torus    {0.8, 0.2 translate  0.8*y}
    torus    {0.8, 0.2 translate -0.8*y}

    /* texture {
        pigment {
            color <1.0, 1.0, 1.0, 0.3>
        }
        finish {
            ambient 0
            diffuse 0.875
        }
    } */
    texture {
        pigment {
            gradient <1, 1, 1>
            color_map {
                [0 color <1, 1, 1, 0.2>] [0.5 color <1, 1, 1, 0.5>]
                [1 color <1, 1, 1, 0.2>]
            }
            warp {
                turbulence 1
            }
            scale 1/2
        }
        finish {
            ambient 0
            diffuse 0.875
        }
    }
}

/* vim: set ts=4 sts=4 sw=4 tw=80 et: */